mit VBA nur bestimmte Anzahl von gefilterter Werte

Forumthread: mit VBA nur bestimmte Anzahl von gefilterter Werte

07.10.2015 14:47:26

gefilterter

Hallo liebe Profis,
ich habe folgendes Problem: ich filtere per VBA eine Liste, kopiere dann die gefilterten Werte und übertrage sie in eine andere Liste.
wie kann ich dem Code klarmachen, dass er, wenn mehr als 10 Werte gefiltert wurden, nur die 10 ersten markiert / kopiert werden sollen? (wg. limitierter Zeilenzahl in der Zieltabelle)
Da die gefilterten Werte Text sind, geht kein Top 10...
Ulrike

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

mit .Resize(10,) o.T.

07.10.2015 20:21:46

Sepp
AW: mit .Resize(10,) o.T.

11.10.2015 14:09:08

u_hoernchen
AW: Maximal 10 Gefilterte

11.10.2015 14:56:28

Gerd
AW: mit .Resize(10,) o.T.

11.10.2015 19:35:31

Sepp
AW: mit .Resize(10,) o.T.

14.10.2015 11:05:45

u_hoernchen

mit .Resize(10,) o.T.

07.10.2015 20:21:46

Sepp

Gruß Sepp

AW: mit .Resize(10,) o.T.

11.10.2015 14:09:08

u_hoernchen

Hallo Sepp,
danke erst einmal für den Tipp, leider funktioniert er nicht bei gefilterten Listen... hast Du noch eine anderen Idee?
ggf. müsste ich die gefilterten Werte irgendwo zwischenparken und dann resize machen?
Ulrike

AW: Maximal 10 Gefilterte

11.10.2015 14:56:28

Gerd

Hallo Ulrike!

Sub a()
Dim lngRow As Long, lngCt As Long
Dim Q As Range
With Tabelle1 'Blatt mit Autofilter
Set Q = .AutoFilter.Range
For lngRow = Q.Row + 1 To Q.Row + Q.Rows.Count - 1
lngCt = lngCt - Not .Rows(lngRow).Hidden
If lngCt = 10 Then Exit For
Next
.Range(.Rows(Q.Row + 1), .Rows(lngRow)).Copy Tabelle2.Cells(2, 1) 'Zielzelle
End With
End Sub

Gruß Gerd

AW: mit .Resize(10,) o.T.

11.10.2015 19:35:31

Sepp

Hallo Ulrike,
dann so.

' **********************************************************************
' Modul: Modul1  Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub firstTen()
Dim rng As Range, rngC As Range, rngSource As Range, rngTarget As Range

On Error GoTo ErrorHandler

Set rngSource = Tabelle1.AutoFilter.Range 'Ausgangstabelle - Anpassen!
Set rngTarget = Tabelle2.Range("A2")      'Zielbereich     - Anpassen!

With rngSource
  For Each rng In .Columns(1).Cells
    If rng.Row > .Cells(1, 1).Row Then
      If Not rng.EntireRow.Hidden Then
        If rngC Is Nothing Then
          Set rngC = rng
        Else
          Set rngC = Union(rngC, rng)
          If rngC.Count = 10 Then
            rngC.EntireRow.Copy rngTarget
            Exit For
          End If
        End If
      End If
    End If
  Next
End With

ErrorHandler:

With Err
  If .Number <> 0 Then
    MsgBox "Fehler in Prozedur:" & vbTab & "'firstTen'" & vbLf & String(60, "_") & _
      vbLf & vbLf & IIf(Erl, "Fehler in Zeile:" & vbTab & Erl & vbLf & vbLf, "") & _
      "Fehlernummer:" & vbTab & .Number & vbLf & vbLf & "Beschreibung:" & vbTab & _
      .Description & vbLf, vbExclamation + vbMsgBoxSetForeground, _
      "VBA - Fehler in Prozedur - firstTen"
    .Clear
  End If
End With

On Error GoTo 0

Set rng = Nothing
Set rngC = Nothing
Set rngSource = Nothing
Set rngTarget = Nothing
End Sub

Gruß Sepp

AW: mit .Resize(10,) o.T.

14.10.2015 11:05:45

u_hoernchen

wow, danke, das gehe ich jetzt mal testen.
ULrike

Beliebteste Forumthreads (12 Monate)

mit VBA nur bestimmte Anzahl von gefilterter Werte

Forumthread: mit VBA nur bestimmte Anzahl von gefilterter Werte

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread